Wild Blue Yonder 1: 50 Years of Gs & Jets/Wild Blue Yonder - Episode 1 - 50 Years of Gs and Jets (Digital Ranch) (Spectrum Holobyte)(1-107-40-101)(1994).iso/control/panel.dir/00749_Script_749

Text File | 1994-08-29 | 6KB | 303 lines

----------------------------------------------------------------------------------------
-- Handlers in this section control the ambient sound.
----------------------------------------------------------------------------------------

on initAmbience
  global ambienceCode

  if ambienceCode <> 1 then
    set ambienceCode = 1
    countSounds
    startAmbience
  end if

end initAmbience




on startAmbience
  chooseChannels
  crossFade
end startAmbience




-- countSounds examines the ambience array to find out how many ambient
-- sounds are associated with the movie.  It stores the total in a
-- variable called overviewSounds.

on countSounds

  global overviewSounds, ambience, ambienceCode

  set overviewSounds = 0
  set contents = 1
  set pointer = ambienceCode

  repeat while pointer < (ambienceCode + 99)
    set contents = ambience( mGet, pointer )
    if contents = 0 then
      exit repeat
    end if
    set pointer = pointer + 1
    set overviewSounds = overviewSounds + 1
  end repeat

end countSounds





on chooseChannels
  global fadeInLength, inChannel, outChannel

  if (the volume of sound 1 > the volume of sound 2) or ¼
    ((the volume of sound 1 < the volume of sound 2) and ¼
     (playTime() < fadeInLength/2)) then
    set inChannel  = 1
    set outChannel = 2
  else
    set inChannel  = 2
    set outChannel = 1
  end if

end chooseChannels





-- crossFade chooses a new cut to play, then fades it in while fading
-- out the old one.

on crossFade
  global inChannel, outChannel, fadeOutLength, fadeInLength

  set temp = inChannel
  set inChannel = outChannel
  set outChannel = temp

  chooseCut

  initFadeOut( outChannel )
  fadeOut( outChannel, fadeOutLength )
  initFadeIn( inChannel )
  fadeIn( inChannel, fadeInLength )
  playCut
end crossFade






on checkAmbience
  global fadedIn, fadedOut, inChannel, outChannel, fadeInLength, ¼
         fadeOutLength

  if not soundBusy( inChannel ) and not soundBusy( outChannel ) then ¼
    startAmbience
  if not fadedIn then fadeIn( inChannel, fadeInLength )
  if not fadedOut then fadeOut( outChannel, fadeOutLength )
  if nearEnd() then crossFade
end checkAmbience






-- chooseCut randomly selects the number of the next cut to play.  If possible, it
-- never repeats the same cut twice in a row.

on chooseCut

  global cut, overviewSounds, oldOverviewSound

  set i = random( overviewSounds )
  set cut = 1 + (i - 1)

  if overviewSounds > 1 then             -- If there are two or more choices, don't repeat.
    if cut = oldOverviewSound then
      chooseCut
    else
      set oldOverviewSound = cut
    end if
  end if

end chooseCut





-- nearEnd checks to see whether the current audio selection has reached
-- the point at which it should start fading out.  (Values were assigned
-- to the array called "fadePoint" in the Overview movie.)

on nearEnd
  global cut, fadePoint

  if playTime() < fadePoint( mGet, cut ) then
    return FALSE
  else
    return TRUE
  end if

end nearEnd




on initFadeOut channel
  global bgVol, lastTimeOut, startVol, fracSumOut, fadedOut, volumes
  set lastTimeOut   = the timer
  set startVol      = volumes( mGet, bgVol )
  set fracSumOut    = 0
  set fadedOut      = FALSE
end initFadeOut





on fadeOut channel, length

  global lastTimeOut, startVol, fracSumOut, fadedOut

  if the timer > lastTimeOut then
    set elapsedTime = (the timer - lastTimeOut) * 1.0000000
    set lastTimeOut = the timer
    set increment = (elapsedTime/length) * startVol
    set increment = storeFractionOut( increment )

    if fracSumOut >= 1 then
      set increment  = increment + 1
      set fracSumOut = fracSumOut - 1
    end if

    set the volume of sound channel = (the volume of sound channel) - increment

    if (the volume of sound channel) = 0 then
      sound stop channel
      set fadedOut = TRUE
    end if

  end if

end fadeOut






on initFadeIn channel
  global lastTimeIn, maxVol, volumes, bgVol, fracSumIn, fadedIn
  set the volume of sound channel = 0
  set lastTimeIn                  = the timer
  set maxVol                      = volumes( mGet, bgVol )
  set fracSumIn                   = 0
  set fadedIn                     = FALSE
end initFadeIn




on fadeIn channel, length

  global lastTimeIn, maxVol, fracSumIn, fadedIn, volumes, bgVol

  if the timer > lastTimeIn then
    set elapsedTime = (the timer - lastTimeIn) * 1.0000000
    set lastTimeIn = the timer
    set increment = (elapsedTime/length) * maxVol
    set increment = storeFractionIn( increment )

    if fracSumIn >= 1 then
      set increment = increment + 1
      set fracSumIn = fracSumIn - 1
    end if

    if ((the volume of sound channel) + increment) < maxVol then
      set the volume of sound channel = (the volume of sound channel) + increment
    else
      set the volume of sound channel = maxVol
      set fadedIn = TRUE
    end if

  end if

end fadeIn




on storeFractionOut n
  global fracSumOut
  set int  = integer( n )
  set frac = n - int

  if frac < 0 then
    set frac = frac + 1
    set int = int - 1
  end if

  set fracSumOut = fracSumOut + frac
  return int
end storeFractionOut




on storeFractionIn n
  global fracSumIn
  set int  = integer( n )
  set frac = n - int

  if frac < 0 then
    set frac = frac + 1
    set int = int - 1
  end if

  set fracSumIn = fracSumIn + frac
  return int
end storeFractionIn




on playCut
  global inChannel, ambience, ambiencePath, CDroot, cut
  set selection = string( ambience( mGet, cut ))
  sound playFile inChannel, CDroot & ambiencePath & selection
  startCutTimer
end playCut




on startCutTimer
  global cutStartTime
  set cutStartTime = the timer
end startCutTimer




on playTime
  global cutStartTime
  return the timer - cutStartTime
end playTime




on stopAmbience
  sound stop 1
  sound stop 2
end stopAmbience